{inputs, ...}: {
  additions = final: _prev: import ../pkgs final.pkgs;

  modifications = final: prev: {
    mods = {
      discord = final.stdenv.mkDerivation {
        pname = "discord-wayland";
        version = prev.discord.version;

        buildInputs = [final.makeWrapper];
        nativeBuildInputs = [final.makeWrapper];

        unpackPhase = "true";
        installPhase = ''
          mkdir -p $out/bin
          ln -s ${prev.discord}/bin/discord $out/bin/.discord-wrapped
          wrapProgram $out/bin/.discord-wrapped \
            --prefix PATH : ${final.lib.makeBinPath [final.xdg-utils final.coreutils]} \
            --add-flags "--enable-features=UseOzonePlatform --ozone-platform=wayland"
          ln -s $out/bin/.discord-wrapped $out/bin/discord
        '';
      };
    };
  };

  unstable-packages = final: prev: {
    unstable = import inputs.nixpkgs-unstable {
      system = final.system;
      config.allowUnfree = true;
    };
  };

  niri = inputs.niri.overlays.niri;
}